
// "viewticket" Function to handle forms
// Submit handler
response = Map();
formValues = Map();
formValues = form.get("values");
if(!formValues.containsKey("dept"))
{
	return {"text":"Your org does not have any active department. Try again after creating one"};
}
orgID = formValues.get("org").get("value");
deptID = formValues.get("dept").get("value");
deptName = formValues.get("dept").get("label");
res = invokeurl
[
	url :"https://desk.zoho.com/api/v1/myinfo"
	type :GET
	headers:{"orgId":orgID}
	connection:"ENTER YOUR CONNECTION NAME"
];
myID = res.get("id");
res = invokeurl
[
	url :"https://desk.zoho.com/api/v1/tickets?departmentIds=" + deptID + "&assignee=" + myID
	type :GET
	headers:{"orgId":orgID}
	connection:"ENTER YOUR CONNECTION NAME"
];
info res;
if(res.get("data").size() > 0)
{
	tickets = res.get("data");
	rows = List();
	for each  ticket in tickets
	{
		item = Map();
		item.put("Ticket Number",ticket.get("ticketNumber"));
		if(ticket.get("dueDate").isNull())
		{
			item.put("Due Date","-");
		}
		else
		{
			item.put("Due Date",ticket.get("dueDate").toDate());
		}
		item.put("View Ticket","[view](" + ticket.get("webUrl") + ")");
		rows.add(item);
	}
}
else
{
	return {"text":"There are no tickets assigned for you in this department :smile:"};
}
response = {"text":"Tickets assigned for you in *" + deptName + "*","card":{"theme":"modern-inline"},"slides":{{"type":"table","title":"","data":{"headers":{"Ticket Number","Due Date","View Ticket"},"rows":rows}}}};
return response;
